git.cworth.org Git - tar/blob - m4/intmax_t.m4

   1 # intmax_t.m4 serial 6
   2 dnl Copyright (C) 1997-2004, 2006-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert.
   8
   9 AC_PREREQ(2.13)
  10
  11 # Define intmax_t to 'long' or 'long long'
  12 # if it is not already defined in <stdint.h> or <inttypes.h>.
  13
  14 AC_DEFUN([gl_AC_TYPE_INTMAX_T],
  15 [
  16   dnl For simplicity, we assume that a header file defines 'intmax_t' if and
  17   dnl only if it defines 'uintmax_t'.
  18   AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
  19   AC_REQUIRE([gl_AC_HEADER_STDINT_H])
  20   if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
  21     AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  22     test $ac_cv_type_long_long_int = yes \
  23       && ac_type='long long' \
  24       || ac_type='long'
  25     AC_DEFINE_UNQUOTED(intmax_t, $ac_type,
  26      [Define to long or long long if <inttypes.h> and <stdint.h> don't define.])
  27   else
  28     AC_DEFINE(HAVE_INTMAX_T, 1,
  29       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
  30   fi
  31 ])
  32
  33 dnl An alternative would be to explicitly test for 'intmax_t'.
  34
  35 AC_DEFUN([gt_AC_TYPE_INTMAX_T],
  36 [
  37   AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
  38   AC_REQUIRE([gl_AC_HEADER_STDINT_H])
  39   AC_CACHE_CHECK(for intmax_t, gt_cv_c_intmax_t,
  40     [AC_TRY_COMPILE([
  41 #include <stddef.h>
  42 #include <stdlib.h>
  43 #if HAVE_STDINT_H_WITH_UINTMAX
  44 #include <stdint.h>
  45 #endif
  46 #if HAVE_INTTYPES_H_WITH_UINTMAX
  47 #include <inttypes.h>
  48 #endif
  49 ], [intmax_t x = -1; return !x;], gt_cv_c_intmax_t=yes, gt_cv_c_intmax_t=no)])
  50   if test $gt_cv_c_intmax_t = yes; then
  51     AC_DEFINE(HAVE_INTMAX_T, 1,
  52       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
  53   else
  54     AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  55     test $ac_cv_type_long_long_int = yes \
  56       && ac_type='long long' \
  57       || ac_type='long'
  58     AC_DEFINE_UNQUOTED(intmax_t, $ac_type,
  59      [Define to long or long long if <stdint.h> and <inttypes.h> don't define.])
  60   fi
  61 ])