git.cworth.org Git - tar/blob - m4/lseek.m4

   1 # lseek.m4 serial 5
   2 dnl Copyright (C) 2007, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LSEEK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_PROG_CC])
  11   AC_CACHE_CHECK([whether lseek detects pipes], [gl_cv_func_lseek_pipe],
  12     [if test $cross_compiling = no; then
  13        AC_LINK_IFELSE([
  14 #include <sys/types.h> /* for off_t */
  15 #include <stdio.h> /* for SEEK_CUR */
  16 #include <unistd.h>
  17 int main ()
  18 {
  19   /* Exit with success only if stdin is seekable.  */
  20   return lseek (0, (off_t)0, SEEK_CUR) < 0;
  21 }],
  22          [if test -s conftest$ac_exeext \
  23              && ./conftest$ac_exeext < conftest.$ac_ext \
  24              && test 1 = "`echo hi \
  25                | { ./conftest$ac_exeext; echo $?; cat >/dev/null; }`"; then
  26             gl_cv_func_lseek_pipe=yes
  27           else
  28             gl_cv_func_lseek_pipe=no
  29           fi],
  30          [gl_cv_func_lseek_pipe=no])
  31      else
  32        AC_COMPILE_IFELSE([
  33 #if ((defined _WIN32 || defined __WIN32__) && ! defined __CYGWIN__) || defined __BEOS__
  34 /* mingw and BeOS mistakenly return 0 when trying to seek on pipes.  */
  35   Choke me.
  36 #endif],
  37          [gl_cv_func_lseek_pipe=yes], [gl_cv_func_lseek_pipe=no])
  38      fi])
  39   if test $gl_cv_func_lseek_pipe = no; then
  40     gl_REPLACE_LSEEK
  41   fi
  42 ])
  43
  44 AC_DEFUN([gl_REPLACE_LSEEK],
  45 [
  46   AC_LIBOBJ([lseek])
  47   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  48   REPLACE_LSEEK=1
  49   AC_DEFINE([LSEEK_PIPE_BROKEN], [1],
  50             [Define to 1 if lseek does not detect pipes.])
  51 ])