git.cworth.org Git - tar/blob - m4/wcwidth.m4

   1 # wcwidth.m4 serial 15
   2 dnl Copyright (C) 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCWIDTH],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11
  12   dnl Persuade glibc <wchar.h> to declare wcwidth().
  13   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_REQUIRE([gt_TYPE_WCHAR_T])
  16   AC_REQUIRE([gt_TYPE_WINT_T])
  17
  18   AC_CHECK_HEADERS_ONCE([wchar.h])
  19   AC_CHECK_FUNCS_ONCE([wcwidth])
  20
  21   AC_CHECK_DECLS([wcwidth], [], [], [
  22 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  23 #include <string.h>
  24 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  25    <wchar.h>.
  26    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  27    before <wchar.h>.  */
  28 #include <stddef.h>
  29 #include <stdio.h>
  30 #include <time.h>
  31 #include <wchar.h>
  32 ])
  33   if test $ac_cv_have_decl_wcwidth != yes; then
  34     HAVE_DECL_WCWIDTH=0
  35   fi
  36
  37   if test $ac_cv_func_wcwidth = no; then
  38     REPLACE_WCWIDTH=1
  39   else
  40     dnl On MacOS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1.
  41     dnl On OSF/1 5.1, wcwidth(0x200B) (ZERO WIDTH SPACE) returns 1.
  42     dnl This leads to bugs in 'ls' (coreutils).
  43     AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales],
  44       [gl_cv_func_wcwidth_works],
  45       [
  46         AC_TRY_RUN([
  47 #include <locale.h>
  48 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  49 #include <string.h>
  50 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  51    <wchar.h>.
  52    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  53    before <wchar.h>.  */
  54 #include <stddef.h>
  55 #include <stdio.h>
  56 #include <time.h>
  57 #include <wchar.h>
  58 #if !HAVE_DECL_WCWIDTH
  59 extern
  60 # ifdef __cplusplus
  61 "C"
  62 # endif
  63 int wcwidth (int);
  64 #endif
  65 int main ()
  66 {
  67   if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL)
  68     if (wcwidth (0x0301) > 0 || wcwidth (0x200B) > 0)
  69       return 1;
  70   return 0;
  71 }], [gl_cv_func_wcwidth_works=yes], [gl_cv_func_wcwidth_works=no],
  72           [
  73 changequote(,)dnl
  74            case "$host_os" in
  75                      # Guess yes on glibc systems.
  76              *-gnu*) gl_cv_func_wcwidth_works="guessing yes";;
  77              *)      gl_cv_func_wcwidth_works="guessing no";;
  78            esac
  79 changequote([,])dnl
  80           ])
  81       ])
  82     case "$gl_cv_func_wcwidth_works" in
  83       *yes) ;;
  84       *no) REPLACE_WCWIDTH=1 ;;
  85     esac
  86   fi
  87   if test $REPLACE_WCWIDTH = 1; then
  88     AC_LIBOBJ([wcwidth])
  89   fi
  90
  91   if test $REPLACE_WCWIDTH = 1 || test $HAVE_DECL_WCWIDTH = 0; then
  92     gl_REPLACE_WCHAR_H
  93   fi
  94 ])