git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  21
  22 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  23
  24
  25 ##############################################################################
  26 # Find dependencies
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33
  34 find_package (Threads)
  35
  36 if (ENABLE_GUI)
  37     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  38         set (REQUIRE_GUI REQUIRED)
  39     endif ()
  40     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  41     find_package (QJSON ${REQUIRE_GUI})
  42 endif ()
  43
  44 if (WIN32)
  45     find_package (DirectX)
  46     set (ENABLE_EGL false)
  47 elseif (APPLE)
  48     set (ENABLE_EGL false)
  49 else ()
  50     find_package (X11)
  51
  52     if (X11_FOUND)
  53         include_directories (${X11_INCLUDE_DIR})
  54         add_definitions (-DHAVE_X11)
  55     endif ()
  56
  57     if (ENABLE_EGL)
  58         add_definitions (-DHAVE_EGL)
  59     endif ()
  60 endif ()
  61
  62
  63 ##############################################################################
  64 # Set global build options
  65
  66 include (CheckCXXCompilerFlag)
  67
  68 if (WIN32)
  69     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  70     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  71 else (WIN32)
  72     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  73     if (CXX_COMPILER_FLAG_VISIBILITY)
  74         add_definitions ("-fvisibility=hidden")
  75     endif (CXX_COMPILER_FLAG_VISIBILITY)
  76 endif (WIN32)
  77
  78 if (MSVC)
  79     # C99 includes for msvc
  80     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  81
  82     # Enable math constants defines
  83     add_definitions (-D_USE_MATH_DEFINES)
  84
  85     # No min/max macros
  86     add_definitions (-DNOMINMAX)
  87
  88     # Adjust warnings
  89     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  90     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  91     add_definitions (-W4)
  92     add_definitions (-wd4063) # not a valid value for switch of enum
  93     add_definitions (-wd4127) # conditional expression is constant
  94     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  95     add_definitions (-wd4505) # unreferenced local function has been removed
  96     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  97     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  98     add_definitions (-wd4018) # signed/unsigned mismatch
  99
 100     # Use static runtime
 101     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 102     foreach (flag_var
 103         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 104         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 105     )
 106         if (${flag_var} MATCHES "/MD")
 107             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 108         endif (${flag_var} MATCHES "/MD")
 109     endforeach (flag_var)
 110 else ()
 111     # Adjust warnings
 112     add_definitions (-Wall)
 113     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 114     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 115 endif ()
 116
 117 if (MINGW)
 118     # Avoid depending on MinGW runtime DLLs
 119     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 120     if (HAVE_STATIC_LIBGCC_FLAG)
 121         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 122         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 123         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 124     endif ()
 125     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 126     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 127         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 128         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 129         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 130     endif ()
 131 endif ()
 132
 133
 134 # Put all executables into the same top level build directory, regardless of
 135 # which subdirectory they are declared
 136 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 137
 138
 139 ##############################################################################
 140 # Bundled dependencies
 141 #
 142 # We always use the bundled zlib, libpng, and snappy sources:
 143 # - on Windows to make it easy to deploy the wrappers DLLs
 144 # - on unices to prevent symbol collisions when tracing applications that link
 145 # against other versions of these libraries
 146
 147 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 148 set (ZLIB_LIBRARIES z_bundled)
 149 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 150
 151 include_directories (${ZLIB_INCLUDE_DIRS})
 152 link_libraries (${ZLIB_LIBRARIES})
 153
 154 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 155 set (SNAPPY_LIBRARIES snappy_bundled)
 156 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 157
 158 include_directories (${SNAPPY_INCLUDE_DIRS})
 159 link_libraries (${SNAPPY_LIBRARIES})
 160
 161 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 162 set (PNG_DEFINITIONS "")
 163 set (PNG_LIBRARIES png_bundled)
 164
 165 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 166 include_directories (${PNG_INCLUDE_DIR})
 167 add_definitions (${PNG_DEFINITIONS})
 168 link_libraries (${PNG_LIBRARIES})
 169
 170 if (MSVC)
 171     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 172     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 173     set (GETOPT_LIBRARIES getopt_bundled)
 174 endif ()
 175
 176 # The Qt website provides binaries for Windows and MacOSX, and they are
 177 # automatically found by cmake without any manual intervention.  The situation
 178 # for QJSON is substantially different: there are no binaries for QJSON
 179 # available, and there is no standard installation directory that is detected
 180 # by cmake.
 181 #
 182 # By bundling the QJSON source, we make it much more easier to build the GUI on
 183 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 184 # AUTO.
 185 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 186     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 187     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 188     set (QJSON_LIBRARY_DIRS)
 189     set (QJSON_LIBRARIES qjson_bundled)
 190     set (QJSON_FOUND TRUE)
 191 endif ()
 192
 193 # We use bundled headers for all Khronos APIs, to guarantee support for both
 194 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 195 # are so intertwined that conditional compilation extremely difficult. This
 196 # also avoids missing/inconsistent declarations in system headers.
 197 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 198
 199 ##############################################################################
 200 # Installation directories
 201
 202 if (WIN32 OR APPLE)
 203     # On Windows/MacOSX, applications are usually installed on a directory of
 204     # their own
 205     set (DOC_INSTALL_DIR doc)
 206     set (LIB_INSTALL_DIR lib)
 207 else ()
 208     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 209     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 210 endif ()
 211
 212 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 213 set(WRAPPER_INSTALL_DIR ${LIB_INSTALL_DIR}/wrappers)
 214
 215 # Expose the binary/install directories to source
 216 #
 217 # TODO: Use the same directory layout, for both build and install directories,
 218 # so that binaries can find each other using just relative paths.
 219 #
 220 add_definitions(
 221     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 222     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 223     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 224 )
 225
 226
 227 ##############################################################################
 228 # Common libraries / utilities
 229
 230 include_directories (
 231     ${CMAKE_CURRENT_BINARY_DIR}
 232     ${CMAKE_CURRENT_SOURCE_DIR}
 233     ${CMAKE_CURRENT_SOURCE_DIR}/common
 234 )
 235
 236 add_custom_command (
 237     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 238     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 239     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 240 )
 241
 242 # Wrap glproc.hpp as a target to prevent the command from being executed
 243 # multiple times simulatenously, when the targets that depend on it are built
 244 # in parallel.
 245 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 246
 247 if (WIN32)
 248     set (os os_win32.cpp)
 249     set (glws_os glws_wgl.cpp)
 250 else ()
 251     set (os os_posix.cpp)
 252     if (APPLE)
 253         set (glws_os glws_cocoa.mm)
 254     else ()
 255         set (glws_os glws_glx.cpp)
 256     endif ()
 257 endif ()
 258
 259 add_library (common STATIC
 260     common/trace_callset.cpp
 261     common/trace_dump.cpp
 262     common/trace_file.cpp
 263     common/trace_file_read.cpp
 264     common/trace_file_write.cpp
 265     common/trace_file_zlib.cpp
 266     common/trace_file_snappy.cpp
 267     common/trace_model.cpp
 268     common/trace_parser.cpp
 269     common/trace_parser_flags.cpp
 270     common/trace_writer.cpp
 271     common/trace_writer_local.cpp
 272     common/trace_writer_model.cpp
 273     common/trace_loader.cpp
 274     common/trace_resource.cpp
 275     common/trace_tools_trace.cpp
 276     common/image.cpp
 277     common/image_bmp.cpp
 278     common/image_pnm.cpp
 279     common/image_png.cpp
 280     common/${os}
 281 )
 282
 283 set_target_properties (common PROPERTIES
 284     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 285     # Ensure it can be statically linked in shared libraries
 286     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 287 )
 288
 289 link_libraries (common)
 290
 291
 292 ##############################################################################
 293 # API tracers
 294
 295 if (WIN32)
 296     if (MINGW)
 297         # Silence warnings about @nn suffix mismatch
 298         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 299     endif (MINGW)
 300
 301     # ddraw.dll
 302     if (DirectX_D3D_INCLUDE_DIR)
 303         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 304         add_custom_command (
 305             OUTPUT ddrawtrace.cpp
 306             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 307             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 308         )
 309         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 310         set_target_properties (ddraw
 311             PROPERTIES PREFIX ""
 312             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 313             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 314         )
 315         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 316     endif (DirectX_D3D_INCLUDE_DIR)
 317
 318     # d3d8.dll
 319     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 320         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 321         add_custom_command (
 322             OUTPUT d3d8trace.cpp
 323             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 324             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 325         )
 326         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 327         set_target_properties (d3d8
 328             PROPERTIES PREFIX ""
 329             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 330             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 331         )
 332         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 333     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 334
 335     # d3d9.dll
 336     if (DirectX_D3DX9_INCLUDE_DIR)
 337         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 338         add_custom_command (
 339             OUTPUT d3d9trace.cpp
 340             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 341             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 342         )
 343         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 344         set_target_properties (d3d9
 345             PROPERTIES PREFIX ""
 346             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 347             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 348         )
 349         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 350     endif (DirectX_D3DX9_INCLUDE_DIR)
 351
 352     # d3d10.dll
 353     if (DirectX_D3D10_INCLUDE_DIR)
 354         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 355         add_custom_command (
 356             OUTPUT d3d10trace.cpp
 357             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 358             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 359         )
 360         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 361         set_target_properties (d3d10
 362             PROPERTIES PREFIX ""
 363             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 364             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 365         )
 366         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 367     endif (DirectX_D3D10_INCLUDE_DIR)
 368
 369     # opengl32.dll
 370     add_custom_command (
 371         OUTPUT wgltrace.cpp
 372         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 373         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 374     )
 375     add_library (wgltrace MODULE specs/opengl32.def
 376         wgltrace.cpp
 377         glcaps.cpp
 378         glproc_gl.cpp
 379     )
 380     add_dependencies (wgltrace glproc)
 381     set_target_properties (wgltrace PROPERTIES
 382         PREFIX ""
 383         OUTPUT_NAME opengl32
 384         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 385         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 386     )
 387     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 388
 389 elseif (APPLE)
 390     # OpenGL framework
 391     add_custom_command (
 392         OUTPUT cgltrace.cpp
 393         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 394         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 395     )
 396
 397     add_library (cgltrace SHARED
 398         cgltrace.cpp
 399         glcaps.cpp
 400         glproc_gl.cpp
 401     )
 402
 403     add_dependencies (cgltrace glproc)
 404
 405     set_target_properties (cgltrace PROPERTIES
 406         # OpenGL framework name
 407         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 408         # Specificy the version and reexport GLU symbols
 409         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 410         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 411         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 412     )
 413
 414     target_link_libraries (cgltrace
 415         ${CMAKE_THREAD_LIBS_INIT}
 416         dl
 417     )
 418
 419     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 420 elseif (X11_FOUND)
 421     # libGL.so
 422     add_custom_command (
 423         OUTPUT glxtrace.cpp
 424         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 425         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 426     )
 427
 428     add_library (glxtrace SHARED
 429         glxtrace.cpp
 430         glcaps.cpp
 431         glproc_gl.cpp
 432     )
 433
 434     add_dependencies (glxtrace glproc)
 435
 436     set_target_properties (glxtrace PROPERTIES
 437         # avoid the default "lib" prefix
 438         PREFIX ""
 439         # Prevent symbol relocations internal to our wrapper library to be
 440         # overwritten by the application.
 441         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 442         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 443         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 444     )
 445
 446     target_link_libraries (glxtrace
 447         ${X11_X11_LIB}
 448         ${CMAKE_THREAD_LIBS_INIT}
 449         dl
 450     )
 451
 452     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 453 endif ()
 454
 455
 456 if (ENABLE_EGL AND NOT WIN32 AND NOT APPLE)
 457     # libEGL.so/libGL.so
 458     add_custom_command (
 459         OUTPUT egltrace.cpp
 460         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 461         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 462     )
 463
 464     add_library (egltrace SHARED
 465         egltrace.cpp
 466         glcaps.cpp
 467         glproc_egl.cpp
 468     )
 469
 470     add_dependencies (egltrace glproc)
 471
 472     set_property (
 473         TARGET egltrace
 474         APPEND
 475         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 476     )
 477
 478     set_target_properties (egltrace PROPERTIES
 479         # avoid the default "lib" prefix
 480         PREFIX ""
 481         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 482         # Prevent symbol relocations internal to our wrapper library to be
 483         # overwritten by the application.
 484         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 485         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 486     )
 487
 488     target_link_libraries (egltrace
 489         ${CMAKE_THREAD_LIBS_INIT}
 490         dl
 491     )
 492
 493     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 494 endif ()
 495
 496 ##############################################################################
 497 # API retracers
 498
 499 add_custom_command (
 500     OUTPUT glretrace_gl.cpp
 501     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 502     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 503 )
 504
 505 add_custom_command (
 506     OUTPUT glstate_params.cpp
 507     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 508     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 509 )
 510
 511 set (retrace_sources
 512     glretrace_gl.cpp
 513     glretrace_cgl.cpp
 514     glretrace_glx.cpp
 515     glretrace_wgl.cpp
 516     glretrace_egl.cpp
 517     glretrace_main.cpp
 518     glstate.cpp
 519     glstate_params.cpp
 520     retrace.cpp
 521     retrace_stdc.cpp
 522     glws.cpp
 523 )
 524
 525 if (WIN32 OR APPLE OR X11_FOUND)
 526     add_executable (glretrace
 527         ${retrace_sources}
 528         ${glws_os}
 529         glproc_gl.cpp
 530     )
 531
 532     add_dependencies (glretrace glproc)
 533
 534     set_property (
 535         TARGET glretrace
 536         APPEND
 537         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 538     )
 539
 540     target_link_libraries (glretrace
 541         common
 542     )
 543
 544     if (WIN32)
 545     else ()
 546         if (APPLE)
 547             target_link_libraries (glretrace
 548                 "-framework Cocoa"
 549                 "-framework ApplicationServices" # CGS*
 550                 #"-framework OpenGL" # CGL*
 551             )
 552         else ()
 553             target_link_libraries (glretrace ${X11_X11_LIB})
 554         endif ()
 555
 556         target_link_libraries (glretrace
 557             # gdb doesn't like when pthreads is loaded through dlopen (which happens
 558             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 559             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 560             ${CMAKE_THREAD_LIBS_INIT}
 561             dl
 562         )
 563
 564         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 565             target_link_libraries (glretrace rt)
 566         endif ()
 567
 568     endif ()
 569
 570     install (TARGETS glretrace RUNTIME DESTINATION bin)
 571 endif ()
 572
 573 if (ENABLE_EGL AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 574     add_executable (eglretrace
 575         ${retrace_sources}
 576         glws_egl_xlib.cpp
 577         glproc_egl.cpp
 578     )
 579
 580     add_dependencies (eglretrace glproc)
 581
 582     set_property (
 583         TARGET eglretrace
 584         APPEND
 585         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 586         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 587     )
 588
 589     target_link_libraries (eglretrace
 590         common
 591         ${X11_X11_LIB}
 592         ${CMAKE_THREAD_LIBS_INIT}
 593         dl
 594     )
 595
 596     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 597         target_link_libraries (eglretrace rt)
 598     endif ()
 599
 600     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 601 endif ()
 602
 603 ##############################################################################
 604 # CLI
 605
 606 if (ENABLE_CLI)
 607     add_subdirectory(cli)
 608 endif ()
 609
 610 ##############################################################################
 611 # Scripts (to support the CLI)
 612
 613 install (
 614     PROGRAMS
 615         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 616         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 617         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 618     DESTINATION ${SCRIPTS_INSTALL_DIR}
 619 )
 620
 621 ##############################################################################
 622 # GUI
 623
 624 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 625     add_subdirectory(gui)
 626 endif ()
 627
 628
 629 ##############################################################################
 630 # Packaging
 631
 632 install (
 633     FILES
 634         BUGS.markdown
 635         LICENSE
 636         NEWS.markdown
 637         README.markdown
 638     DESTINATION ${DOC_INSTALL_DIR}
 639 )
 640
 641 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 642 set (CPACK_PACKAGE_VERSION_MINOR "0")
 643
 644 # Use current date in YYYYMMDD format as patch number
 645 execute_process (
 646     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 647     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 648 )
 649
 650 # cpack mistakenly detects Mingw-w64 as win32
 651 if (MINGW)
 652     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 653         set (CPACK_SYSTEM_NAME win64)
 654     endif ()
 655 endif ()
 656
 657 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 658 if (WIN32)
 659     set (CPACK_GENERATOR "ZIP")
 660 elseif (APPLE)
 661     set (CPACK_GENERATOR "DragNDrop")
 662 else ()
 663     set (CPACK_GENERATOR "TBZ2")
 664 endif ()
 665
 666 include(CPack)