git.cworth.org Git - tar/blob - m4/fdopendir.m4

   1 # serial 4
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14   dnl FreeBSD 7.3 has the function, but failed to declare it.
  15   AC_CHECK_DECLS([fdopendir], [], [HAVE_DECL_FDOPENDIR=0], [[
  16 #include <dirent.h>
  17     ]])
  18   AC_CHECK_FUNCS_ONCE([fdopendir])
  19   if test $ac_cv_func_fdopendir = no; then
  20     AC_LIBOBJ([openat-proc])
  21     AC_LIBOBJ([fdopendir])
  22     gl_REPLACE_DIRENT_H
  23     HAVE_FDOPENDIR=0
  24   else
  25     AC_CACHE_CHECK([whether fdopendir works],
  26       [gl_cv_func_fdopendir_works],
  27       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  28 #include <dirent.h>
  29 #include <fcntl.h>
  30 #if !HAVE_DECL_FDOPENDIR
  31 extern DIR *fdopendir (int);
  32 #endif
  33 ]], [int fd = open ("conftest.c", O_RDONLY);
  34      if (fd < 0) return 2;
  35      return !!fdopendir (fd);])],
  36          [gl_cv_func_fdopendir_works=yes],
  37          [gl_cv_func_fdopendir_works=no],
  38          [gl_cv_func_fdopendir_works="guessing no"])])
  39     if test "$gl_cv_func_fdopendir_works" != yes; then
  40       REPLACE_FDOPENDIR=1
  41       gl_REPLACE_DIRENT_H
  42       AC_LIBOBJ([fdopendir])
  43     fi
  44   fi
  45 ])