git.cworth.org Git - tar/blob - m4/fnmatch.m4

   1 # Check for fnmatch - serial 4.
   2
   3 # Copyright (C) 2000-2007, 2009-2010 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Autoconf defines AC_FUNC_FNMATCH, but that is obsolescent.
   9 # New applications should use the macros below instead.
  10
  11 # Request a POSIX compliant fnmatch function.
  12 AC_DEFUN([gl_FUNC_FNMATCH_POSIX],
  13 [
  14   m4_divert_text([DEFAULTS], [gl_fnmatch_required=POSIX])
  15
  16   dnl Persuade glibc <fnmatch.h> to declare FNM_CASEFOLD etc.
  17   dnl This is only needed if gl_fnmatch_required = GNU. It would be possible
  18   dnl to avoid this dependency for gl_FUNC_FNMATCH_POSIX by putting
  19   dnl gl_FUNC_FNMATCH_GNU into a separate .m4 file.
  20   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  21
  22   FNMATCH_H=
  23   gl_fnmatch_required_lowercase=`
  24     echo $gl_fnmatch_required | tr '[[A-Z]]' '[[a-z]]'
  25   `
  26   gl_fnmatch_cache_var="gl_cv_func_fnmatch_${gl_fnmatch_required_lowercase}"
  27   AC_CACHE_CHECK([for working $gl_fnmatch_required fnmatch],
  28     [$gl_fnmatch_cache_var],
  29     [dnl Some versions of Solaris, SCO, and the GNU C Library
  30      dnl have a broken or incompatible fnmatch.
  31      dnl So we run a test program.  If we are cross-compiling, take no chance.
  32      dnl Thanks to John Oleynick, François Pinard, and Paul Eggert for this
  33      dnl test.
  34      if test $gl_fnmatch_required = GNU; then
  35        gl_fnmatch_gnu_start=
  36        gl_fnmatch_gnu_end=
  37      else
  38        gl_fnmatch_gnu_start='#if 0'
  39        gl_fnmatch_gnu_end='#endif'
  40      fi
  41      AC_RUN_IFELSE(
  42        [AC_LANG_PROGRAM(
  43           [[#include <fnmatch.h>
  44             static int
  45             y (char const *pattern, char const *string, int flags)
  46             {
  47               return fnmatch (pattern, string, flags) == 0;
  48             }
  49             static int
  50             n (char const *pattern, char const *string, int flags)
  51             {
  52               return fnmatch (pattern, string, flags) == FNM_NOMATCH;
  53             }
  54           ]],
  55           [[char const *Apat = 'A' < '\\\\' ? "[A-\\\\\\\\]" : "[\\\\\\\\-A]";
  56             char const *apat = 'a' < '\\\\' ? "[a-\\\\\\\\]" : "[\\\\\\\\-a]";
  57             static char const A_1[] = { 'A' - 1, 0 };
  58             static char const A01[] = { 'A' + 1, 0 };
  59             static char const a_1[] = { 'a' - 1, 0 };
  60             static char const a01[] = { 'a' + 1, 0 };
  61             static char const bs_1[] = { '\\\\' - 1, 0 };
  62             static char const bs01[] = { '\\\\' + 1, 0 };
  63             return
  64              !(n ("a*", "", 0)
  65                && y ("a*", "abc", 0)
  66                && n ("d*/*1", "d/s/1", FNM_PATHNAME)
  67                && y ("a\\\\bc", "abc", 0)
  68                && n ("a\\\\bc", "abc", FNM_NOESCAPE)
  69                && y ("*x", ".x", 0)
  70                && n ("*x", ".x", FNM_PERIOD)
  71                && y (Apat, "\\\\", 0) && y (Apat, "A", 0)
  72                && y (apat, "\\\\", 0) && y (apat, "a", 0)
  73                && n (Apat, A_1, 0) == ('A' < '\\\\')
  74                && n (apat, a_1, 0) == ('a' < '\\\\')
  75                && y (Apat, A01, 0) == ('A' < '\\\\')
  76                && y (apat, a01, 0) == ('a' < '\\\\')
  77                && y (Apat, bs_1, 0) == ('A' < '\\\\')
  78                && y (apat, bs_1, 0) == ('a' < '\\\\')
  79                && n (Apat, bs01, 0) == ('A' < '\\\\')
  80                && n (apat, bs01, 0) == ('a' < '\\\\')
  81                $gl_fnmatch_gnu_start
  82                && y ("xxXX", "xXxX", FNM_CASEFOLD)
  83                && y ("a++(x|yy)b", "a+xyyyyxb", FNM_EXTMATCH)
  84                && n ("d*/*1", "d/s/1", FNM_FILE_NAME)
  85                && y ("*", "x", FNM_FILE_NAME | FNM_LEADING_DIR)
  86                && y ("x*", "x/y/z", FNM_FILE_NAME | FNM_LEADING_DIR)
  87                && y ("*c*", "c/x", FNM_FILE_NAME | FNM_LEADING_DIR)
  88                $gl_fnmatch_gnu_end
  89               );
  90           ]])],
  91        [eval "$gl_fnmatch_cache_var=yes"],
  92        [eval "$gl_fnmatch_cache_var=no"],
  93        [eval "$gl_fnmatch_cache_var=\"guessing no\""])
  94     ])
  95   eval "gl_fnmatch_result=\"\$$gl_fnmatch_cache_var\""
  96   if test "$gl_fnmatch_result" = yes; then
  97     dnl Not strictly necessary. Only to avoid spurious leftover files if people
  98     dnl don't do "make distclean".
  99     rm -f "$gl_source_base/fnmatch.h"
 100   else
 101     FNMATCH_H=fnmatch.h
 102     AC_LIBOBJ([fnmatch])
 103     dnl We must choose a different name for our function, since on ELF systems
 104     dnl a broken fnmatch() in libc.so would override our fnmatch() if it is
 105     dnl compiled into a shared library.
 106     AC_DEFINE_UNQUOTED([fnmatch], [${gl_fnmatch_required_lowercase}_fnmatch],
 107       [Define to a replacement function name for fnmatch().])
 108     dnl Prerequisites of lib/fnmatch.c.
 109     AC_REQUIRE([AC_TYPE_MBSTATE_T])
 110     AC_CHECK_DECLS([isblank], [], [], [#include <ctype.h>])
 111     AC_CHECK_FUNCS_ONCE([btowc isblank iswctype mbsrtowcs mempcpy wmemchr wmemcpy wmempcpy])
 112     AC_CHECK_HEADERS_ONCE([wctype.h])
 113   fi
 114   AC_SUBST([FNMATCH_H])
 115 ])
 116
 117 # Request a POSIX compliant fnmatch function with GNU extensions.
 118 AC_DEFUN([gl_FUNC_FNMATCH_GNU],
 119 [
 120   m4_divert_text([INIT_PREPARE], [gl_fnmatch_required=GNU])
 121
 122   AC_REQUIRE([gl_FUNC_FNMATCH_POSIX])
 123 ])