git.cworth.org Git - tar/blob - m4/fpending.m4

   1 # serial 14
   2
   3 # Copyright (C) 2000-2001, 2004-2009 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Jim Meyering
   9 dnl Using code from emacs, based on suggestions from Paul Eggert
  10 dnl and Ulrich Drepper.
  11
  12 dnl Find out how to determine the number of pending output bytes on a stream.
  13 dnl glibc (2.1.93 and newer) and Solaris provide __fpending.  On other systems,
  14 dnl we have to grub around in the FILE struct.
  15
  16 AC_DEFUN([gl_FUNC_FPENDING],
  17 [
  18   AC_CHECK_HEADERS_ONCE([stdio_ext.h])
  19   AC_CHECK_FUNCS_ONCE([__fpending])
  20   fp_headers='
  21 #     include <stdio.h>
  22 #     if HAVE_STDIO_EXT_H
  23 #      include <stdio_ext.h>
  24 #     endif
  25 '
  26   AC_CHECK_DECLS([__fpending], , , $fp_headers)
  27   if test $ac_cv_func___fpending = no; then
  28     AC_CACHE_CHECK(
  29               [how to determine the number of pending output bytes on a stream],
  30                    ac_cv_sys_pending_output_n_bytes,
  31       [
  32         for ac_expr in                                                    \
  33                                                                           \
  34             '# glibc2'                                                    \
  35             'fp->_IO_write_ptr - fp->_IO_write_base'                      \
  36                                                                           \
  37             '# traditional Unix'                                          \
  38             'fp->_ptr - fp->_base'                                        \
  39                                                                           \
  40             '# BSD'                                                       \
  41             'fp->_p - fp->_bf._base'                                      \
  42                                                                           \
  43             '# SCO, Unixware'                                             \
  44             '(fp->__ptr ? fp->__ptr - fp->__base : 0)'                    \
  45                                                                           \
  46             '# QNX'                                                       \
  47             '(fp->_Mode & 0x2000 /*_MWRITE*/ ? fp->_Next - fp->_Buf : 0)' \
  48                                                                           \
  49             '# old glibc?'                                                \
  50             'fp->__bufp - fp->__buffer'                                   \
  51                                                                           \
  52             '# old glibc iostream?'                                       \
  53             'fp->_pptr - fp->_pbase'                                      \
  54                                                                           \
  55             '# emx+gcc'                                                   \
  56             'fp->_ptr - fp->_buffer'                                      \
  57                                                                           \
  58             '# VMS'                                                       \
  59             '(*fp)->_ptr - (*fp)->_base'                                  \
  60                                                                           \
  61             '# e.g., DGUX R4.11; the info is not available'               \
  62             1                                                             \
  63             ; do
  64
  65           # Skip each embedded comment.
  66           case "$ac_expr" in '#'*) continue;; esac
  67
  68           AC_TRY_COMPILE(
  69             [#include <stdio.h>
  70             ],
  71             [FILE *fp = stdin; (void) ($ac_expr);],
  72             fp_done=yes
  73           )
  74           test "$fp_done" = yes && break
  75         done
  76
  77         ac_cv_sys_pending_output_n_bytes=$ac_expr
  78       ]
  79     )
  80     AC_DEFINE_UNQUOTED([PENDING_OUTPUT_N_BYTES],
  81       $ac_cv_sys_pending_output_n_bytes,
  82       [the number of pending output bytes on stream `fp'])
  83     AC_LIBOBJ([fpending])
  84   fi
  85 ])