git.cworth.org Git - tar/blob - m4/fseeko.m4

   1 # fseeko.m4 serial 9
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([gl_HAVE_FSEEKO])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   if test $gl_cv_func_fseeko = no; then
  14     HAVE_FSEEKO=0
  15     gl_REPLACE_FSEEKO
  16   else
  17     if test $gl_cv_var_stdin_large_offset = no; then
  18       gl_REPLACE_FSEEKO
  19     fi
  20   fi
  21 ])
  22
  23 dnl Tests whether fseeko is available.
  24 dnl Result is gl_cv_func_fseeko.
  25 AC_DEFUN([gl_HAVE_FSEEKO],
  26 [
  27   AC_REQUIRE([AC_PROG_CC])
  28
  29   dnl Persuade glibc <stdio.h> to declare fseeko().
  30   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  31
  32   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  33     [
  34       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
  35 ]], [fseeko (stdin, 0, 0);])],
  36         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  37     ])
  38 ])
  39
  40 AC_DEFUN([gl_REPLACE_FSEEKO],
  41 [
  42   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  43   AC_REQUIRE([gl_HAVE_FSEEKO])
  44   if test $gl_cv_func_fseeko = yes; then
  45     REPLACE_FSEEKO=1
  46   fi
  47   AC_LIBOBJ([fseeko])
  48   dnl If we are also using the fseek module, then fseek needs replacing, too.
  49   m4_ifdef([gl_REPLACE_FSEEK], [gl_REPLACE_FSEEK])
  50 ])