git.cworth.org Git - tar/blob - m4/include_next.m4

   1 # include_next.m4 serial 16
   2 dnl Copyright (C) 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Derek Price.
   8
   9 dnl Sets INCLUDE_NEXT and PRAGMA_SYSTEM_HEADER.
  10 dnl
  11 dnl INCLUDE_NEXT expands to 'include_next' if the compiler supports it, or to
  12 dnl 'include' otherwise.
  13 dnl
  14 dnl INCLUDE_NEXT_AS_FIRST_DIRECTIVE expands to 'include_next' if the compiler
  15 dnl supports it in the special case that it is the first include directive in
  16 dnl the given file, or to 'include' otherwise.
  17 dnl
  18 dnl PRAGMA_SYSTEM_HEADER can be used in files that contain #include_next,
  19 dnl so as to avoid GCC warnings when the gcc option -pedantic is used.
  20 dnl '#pragma GCC system_header' has the same effect as if the file was found
  21 dnl through the include search path specified with '-isystem' options (as
  22 dnl opposed to the search path specified with '-I' options). Namely, gcc
  23 dnl does not warn about some things, and on some systems (Solaris and Interix)
  24 dnl __STDC__ evaluates to 0 instead of to 1. The latter is an undesired side
  25 dnl effect; we are therefore careful to use 'defined __STDC__' or '1' instead
  26 dnl of plain '__STDC__'.
  27 dnl
  28 dnl PRAGMA_COLUMNS can be used in files that override system header files, so
  29 dnl as to avoid compilation errors on HP NonStop systems when the gnulib file
  30 dnl is included by a system header file that does a "#pragma COLUMNS 80" (which
  31 dnl has the effect of truncating the lines of that file and all files that it
  32 dnl includes to 80 columns) and the gnulib file has lines longer than 80
  33 dnl columns.
  34
  35 AC_DEFUN([gl_INCLUDE_NEXT],
  36 [
  37   AC_LANG_PREPROC_REQUIRE()
  38   AC_CACHE_CHECK([whether the preprocessor supports include_next],
  39     [gl_cv_have_include_next],
  40     [rm -rf conftestd1a conftestd1b conftestd2
  41      mkdir conftestd1a conftestd1b conftestd2
  42      dnl IBM C 9.0, 10.1 (original versions, prior to the 2009-01 updates) on
  43      dnl AIX 6.1 support include_next when used as first preprocessor directive
  44      dnl in a file, but not when preceded by another include directive. Check
  45      dnl for this bug by including <stdio.h>.
  46      dnl Additionally, with this same compiler, include_next is a no-op when
  47      dnl used in a header file that was included by specifying its absolute
  48      dnl file name. Despite these two bugs, include_next is used in the
  49      dnl compiler's <math.h>. By virtue of the second bug, we need to use
  50      dnl include_next as well in this case.
  51      cat <<EOF > conftestd1a/conftest.h
  52 #define DEFINED_IN_CONFTESTD1
  53 #include_next <conftest.h>
  54 #ifdef DEFINED_IN_CONFTESTD2
  55 int foo;
  56 #else
  57 #error "include_next doesn't work"
  58 #endif
  59 EOF
  60      cat <<EOF > conftestd1b/conftest.h
  61 #define DEFINED_IN_CONFTESTD1
  62 #include <stdio.h>
  63 #include_next <conftest.h>
  64 #ifdef DEFINED_IN_CONFTESTD2
  65 int foo;
  66 #else
  67 #error "include_next doesn't work"
  68 #endif
  69 EOF
  70      cat <<EOF > conftestd2/conftest.h
  71 #ifndef DEFINED_IN_CONFTESTD1
  72 #error "include_next test doesn't work"
  73 #endif
  74 #define DEFINED_IN_CONFTESTD2
  75 EOF
  76      gl_save_CPPFLAGS="$CPPFLAGS"
  77      CPPFLAGS="$gl_save_CPPFLAGS -Iconftestd1b -Iconftestd2"
  78 dnl We intentionally avoid using AC_LANG_SOURCE here.
  79      AC_COMPILE_IFELSE([AC_LANG_DEFINES_PROVIDED[#include <conftest.h>]],
  80        [gl_cv_have_include_next=yes],
  81        [CPPFLAGS="$gl_save_CPPFLAGS -Iconftestd1a -Iconftestd2"
  82         AC_COMPILE_IFELSE([AC_LANG_DEFINES_PROVIDED[#include <conftest.h>]],
  83           [gl_cv_have_include_next=buggy],
  84           [gl_cv_have_include_next=no])
  85        ])
  86      CPPFLAGS="$gl_save_CPPFLAGS"
  87      rm -rf conftestd1a conftestd1b conftestd2
  88     ])
  89   PRAGMA_SYSTEM_HEADER=
  90   if test $gl_cv_have_include_next = yes; then
  91     INCLUDE_NEXT=include_next
  92     INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include_next
  93     if test -n "$GCC"; then
  94       PRAGMA_SYSTEM_HEADER='#pragma GCC system_header'
  95     fi
  96   else
  97     if test $gl_cv_have_include_next = buggy; then
  98       INCLUDE_NEXT=include
  99       INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include_next
 100     else
 101       INCLUDE_NEXT=include
 102       INCLUDE_NEXT_AS_FIRST_DIRECTIVE=include
 103     fi
 104   fi
 105   AC_SUBST([INCLUDE_NEXT])
 106   AC_SUBST([INCLUDE_NEXT_AS_FIRST_DIRECTIVE])
 107   AC_SUBST([PRAGMA_SYSTEM_HEADER])
 108   AC_CACHE_CHECK([whether system header files limit the line length],
 109     [gl_cv_pragma_columns],
 110     [dnl HP NonStop systems, which define __TANDEM, have this misfeature.
 111      AC_EGREP_CPP([choke me],
 112        [
 113 #ifdef __TANDEM
 114 choke me
 115 #endif
 116        ],
 117        [gl_cv_pragma_columns=yes],
 118        [gl_cv_pragma_columns=no])
 119     ])
 120   if test $gl_cv_pragma_columns = yes; then
 121     PRAGMA_COLUMNS="#pragma COLUMNS 10000"
 122   else
 123     PRAGMA_COLUMNS=
 124   fi
 125   AC_SUBST([PRAGMA_COLUMNS])
 126 ])
 127
 128 # gl_CHECK_NEXT_HEADERS(HEADER1 HEADER2 ...)
 129 # ------------------------------------------
 130 # For each arg foo.h, if #include_next works, define NEXT_FOO_H to be
 131 # '<foo.h>'; otherwise define it to be
 132 # '"///usr/include/foo.h"', or whatever other absolute file name is suitable.
 133 # Also, if #include_next works as first preprocessing directive in a file,
 134 # define NEXT_AS_FIRST_DIRECTIVE_FOO_H to be '<foo.h>'; otherwise define it to
 135 # be
 136 # '"///usr/include/foo.h"', or whatever other absolute file name is suitable.
 137 # That way, a header file with the following line:
 138 #       #@INCLUDE_NEXT@ @NEXT_FOO_H@
 139 # or
 140 #       #@INCLUDE_NEXT_AS_FIRST_DIRECTIVE@ @NEXT_AS_FIRST_DIRECTIVE_FOO_H@
 141 # behaves (after sed substitution) as if it contained
 142 #       #include_next <foo.h>
 143 # even if the compiler does not support include_next.
 144 # The three "///" are to pacify Sun C 5.8, which otherwise would say
 145 # "warning: #include of /usr/include/... may be non-portable".
 146 # Use `""', not `<>', so that the /// cannot be confused with a C99 comment.
 147 # Note: This macro assumes that the header file is not empty after
 148 # preprocessing, i.e. it does not only define preprocessor macros but also
 149 # provides some type/enum definitions or function/variable declarations.
 150 AC_DEFUN([gl_CHECK_NEXT_HEADERS],
 151 [
 152   AC_REQUIRE([gl_INCLUDE_NEXT])
 153   AC_REQUIRE([AC_CANONICAL_HOST])
 154   AC_CHECK_HEADERS_ONCE([$1])
 155
 156   m4_foreach_w([gl_HEADER_NAME], [$1],
 157     [AS_VAR_PUSHDEF([gl_next_header],
 158                     [gl_cv_next_]m4_defn([gl_HEADER_NAME]))
 159      if test $gl_cv_have_include_next = yes; then
 160        AS_VAR_SET([gl_next_header], ['<'gl_HEADER_NAME'>'])
 161      else
 162        AC_CACHE_CHECK(
 163          [absolute name of <]m4_defn([gl_HEADER_NAME])[>],
 164          m4_defn([gl_next_header]),
 165          [AS_VAR_PUSHDEF([gl_header_exists],
 166                          [ac_cv_header_]m4_defn([gl_HEADER_NAME]))
 167           if test AS_VAR_GET(gl_header_exists) = yes; then
 168             AC_LANG_CONFTEST(
 169               [AC_LANG_SOURCE(
 170                  [[#include <]]m4_dquote(m4_defn([gl_HEADER_NAME]))[[>]]
 171                )])
 172             dnl AIX "xlc -E" and "cc -E" omit #line directives for header files
 173             dnl that contain only a #include of other header files and no
 174             dnl non-comment tokens of their own. This leads to a failure to
 175             dnl detect the absolute name of <dirent.h>, <signal.h>, <poll.h>
 176             dnl and others. The workaround is to force preservation of comments
 177             dnl through option -C. This ensures all necessary #line directives
 178             dnl are present. GCC supports option -C as well.
 179             case "$host_os" in
 180               aix*) gl_absname_cpp="$ac_cpp -C" ;;
 181               *)    gl_absname_cpp="$ac_cpp" ;;
 182             esac
 183             dnl eval is necessary to expand gl_absname_cpp.
 184             dnl Ultrix and Pyramid sh refuse to redirect output of eval,
 185             dnl so use subshell.
 186             AS_VAR_SET([gl_next_header],
 187               ['"'`(eval "$gl_absname_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
 188                sed -n '\#/]m4_defn([gl_HEADER_NAME])[#{
 189                  s#.*"\(.*/]m4_defn([gl_HEADER_NAME])[\)".*#\1#
 190                  s#^/[^/]#//&#
 191                  p
 192                  q
 193                }'`'"'])
 194           else
 195             AS_VAR_SET([gl_next_header], ['<'gl_HEADER_NAME'>'])
 196           fi
 197           AS_VAR_POPDEF([gl_header_exists])])
 198      fi
 199      AC_SUBST(
 200        AS_TR_CPP([NEXT_]m4_defn([gl_HEADER_NAME])),
 201        [AS_VAR_GET([gl_next_header])])
 202      if test $gl_cv_have_include_next = yes || test $gl_cv_have_include_next = buggy; then
 203        # INCLUDE_NEXT_AS_FIRST_DIRECTIVE='include_next'
 204        gl_next_as_first_directive='<'gl_HEADER_NAME'>'
 205      else
 206        # INCLUDE_NEXT_AS_FIRST_DIRECTIVE='include'
 207        gl_next_as_first_directive=AS_VAR_GET([gl_next_header])
 208      fi
 209      AC_SUBST(
 210        AS_TR_CPP([NEXT_AS_FIRST_DIRECTIVE_]m4_defn([gl_HEADER_NAME])),
 211        [$gl_next_as_first_directive])
 212      AS_VAR_POPDEF([gl_next_header])])
 213 ])
 214
 215 # Autoconf 2.68 added warnings for our use of AC_COMPILE_IFELSE;
 216 # this fallback is safe for all earlier autoconf versions.
 217 m4_define_default([AC_LANG_DEFINES_PROVIDED])