git.cworth.org Git - tar/blob - m4/locale-zh.m4

   1 # locale-zh.m4 serial 7
   2 dnl Copyright (C) 2003, 2005-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl Determine the name of a chinese locale with GB18030 encoding.
  10 AC_DEFUN([gt_LOCALE_ZH_CN],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a transitional chinese locale], [gt_cv_locale_zh_CN], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([
  16 changequote(,)dnl
  17 #include <locale.h>
  18 #include <stdlib.h>
  19 #include <time.h>
  20 #if HAVE_LANGINFO_CODESET
  21 # include <langinfo.h>
  22 #endif
  23 #include <stdlib.h>
  24 #include <string.h>
  25 struct tm t;
  26 char buf[16];
  27 int main ()
  28 {
  29   const char *p;
  30   /* Check whether the given locale name is recognized by the system.  */
  31   if (setlocale (LC_ALL, "") == NULL) return 1;
  32   /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
  33      On MacOS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
  34      is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
  35      On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
  36      succeeds but then nl_langinfo(CODESET) is "646". In this situation,
  37      some unit tests fail.
  38      On MirBSD 10, when an unsupported locale is specified, setlocale()
  39      succeeds but then nl_langinfo(CODESET) is "UTF-8".  */
  40 #if HAVE_LANGINFO_CODESET
  41   {
  42     const char *cs = nl_langinfo (CODESET);
  43     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  44         || strcmp (cs, "UTF-8") == 0)
  45       return 1;
  46   }
  47 #endif
  48 #ifdef __CYGWIN__
  49   /* On Cygwin, avoid locale names without encoding suffix, because the
  50      locale_charset() function relies on the encoding suffix.  Note that
  51      LC_ALL is set on the command line.  */
  52   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  53 #endif
  54   /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
  55      This excludes the UTF-8 encoding (except on MirBSD).  */
  56   t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
  57   if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
  58   for (p = buf; *p != '\0'; p++)
  59     if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
  60       return 1;
  61   /* Check whether a typical GB18030 multibyte sequence is recognized as a
  62      single wide character.  This excludes the GB2312 and GBK encodings.  */
  63   if (mblen ("\203\062\332\066", 5) != 4)
  64     return 1;
  65   return 0;
  66 }
  67 changequote([,])dnl
  68       ])])
  69     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  70       # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  71       # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
  72       # configure script would override the LC_ALL setting. Likewise for
  73       # LC_CTYPE, which is also set at the beginning of the configure script.
  74       # Test for the locale name without encoding suffix.
  75       if (LC_ALL=zh_CN LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  76         gt_cv_locale_zh_CN=zh_CN
  77       else
  78         # Test for the locale name with explicit encoding suffix.
  79         if (LC_ALL=zh_CN.GB18030 LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  80           gt_cv_locale_zh_CN=zh_CN.GB18030
  81         else
  82           # None found.
  83           gt_cv_locale_zh_CN=none
  84         fi
  85       fi
  86     else
  87       # If there was a link error, due to mblen(), the system is so old that
  88       # it certainly doesn't have a chinese locale.
  89       gt_cv_locale_zh_CN=none
  90     fi
  91     rm -fr conftest*
  92   ])
  93   LOCALE_ZH_CN=$gt_cv_locale_zh_CN
  94   AC_SUBST([LOCALE_ZH_CN])
  95 ])