git.cworth.org Git - tar/blob - m4/lseek.m4

   1 # lseek.m4 serial 6
   2 dnl Copyright (C) 2007, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LSEEK],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_PROG_CC])
  11   AC_CACHE_CHECK([whether lseek detects pipes], [gl_cv_func_lseek_pipe],
  12     [if test $cross_compiling = no; then
  13        AC_LINK_IFELSE([AC_LANG_PROGRAM([[
  14 #include <sys/types.h> /* for off_t */
  15 #include <stdio.h> /* for SEEK_CUR */
  16 #include <unistd.h>]], [[
  17   /* Exit with success only if stdin is seekable.  */
  18   return lseek (0, (off_t)0, SEEK_CUR) < 0;
  19 ]])],
  20          [if test -s conftest$ac_exeext \
  21              && ./conftest$ac_exeext < conftest.$ac_ext \
  22              && test 1 = "`echo hi \
  23                | { ./conftest$ac_exeext; echo $?; cat >/dev/null; }`"; then
  24             gl_cv_func_lseek_pipe=yes
  25           else
  26             gl_cv_func_lseek_pipe=no
  27           fi],
  28          [gl_cv_func_lseek_pipe=no])
  29      else
  30        AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  31 #if ((defined _WIN32 || defined __WIN32__) && ! defined __CYGWIN__) || defined __BEOS__
  32 /* mingw and BeOS mistakenly return 0 when trying to seek on pipes.  */
  33   Choke me.
  34 #endif]])],
  35          [gl_cv_func_lseek_pipe=yes], [gl_cv_func_lseek_pipe=no])
  36      fi])
  37   if test $gl_cv_func_lseek_pipe = no; then
  38     gl_REPLACE_LSEEK
  39   fi
  40 ])
  41
  42 AC_DEFUN([gl_REPLACE_LSEEK],
  43 [
  44   AC_LIBOBJ([lseek])
  45   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  46   REPLACE_LSEEK=1
  47   AC_DEFINE([LSEEK_PIPE_BROKEN], [1],
  48             [Define to 1 if lseek does not detect pipes.])
  49 ])