git.cworth.org Git - tar/blob - m4/open.m4

   1 # open.m4 serial 9
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_OPEN],
   8 [
   9   AC_REQUIRE([AC_CANONICAL_HOST])
  10   case "$host_os" in
  11     mingw* | pw*)
  12       gl_REPLACE_OPEN
  13       ;;
  14     *)
  15       dnl open("foo/") should not create a file when the file name has a
  16       dnl trailing slash.  FreeBSD only has the problem on symlinks.
  17       AC_CHECK_FUNCS_ONCE([lstat])
  18       AC_CACHE_CHECK([whether open recognizes a trailing slash],
  19         [gl_cv_func_open_slash],
  20         [# Assume that if we have lstat, we can also check symlinks.
  21           if test $ac_cv_func_lstat = yes; then
  22             touch conftest.tmp
  23             ln -s conftest.tmp conftest.lnk
  24           fi
  25           AC_RUN_IFELSE(
  26             [AC_LANG_SOURCE([[
  27 #include <fcntl.h>
  28 #if HAVE_UNISTD_H
  29 # include <unistd.h>
  30 #endif
  31 int main ()
  32 {
  33 #if HAVE_LSTAT
  34   if (open ("conftest.lnk/", O_RDONLY) != -1) return 2;
  35 #endif
  36   return open ("conftest.sl/", O_CREAT, 0600) >= 0;
  37 }]])],
  38             [gl_cv_func_open_slash=yes],
  39             [gl_cv_func_open_slash=no],
  40             [
  41 changequote(,)dnl
  42              case "$host_os" in
  43                freebsd* | aix* | hpux* | solaris2.[0-9]*)
  44                  gl_cv_func_open_slash="guessing no" ;;
  45                *)
  46                  gl_cv_func_open_slash="guessing yes" ;;
  47              esac
  48 changequote([,])dnl
  49             ])
  50           rm -f conftest.sl conftest.tmp conftest.lnk
  51         ])
  52       case "$gl_cv_func_open_slash" in
  53         *no)
  54           AC_DEFINE([OPEN_TRAILING_SLASH_BUG], [1],
  55             [Define to 1 if open() fails to recognize a trailing slash.])
  56           gl_REPLACE_OPEN
  57           ;;
  58       esac
  59       ;;
  60   esac
  61 ])
  62
  63 AC_DEFUN([gl_REPLACE_OPEN],
  64 [
  65   AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
  66   REPLACE_OPEN=1
  67   AC_LIBOBJ([open])
  68   gl_PREREQ_OPEN
  69 ])
  70
  71 # Prerequisites of lib/open.c.
  72 AC_DEFUN([gl_PREREQ_OPEN],
  73 [
  74   AC_REQUIRE([AC_C_INLINE])
  75   AC_REQUIRE([gl_PROMOTED_TYPE_MODE_T])
  76   :
  77 ])