git.cworth.org Git - tar/blob - m4/realloc.m4

   1 # realloc.m4 serial 11
   2 dnl Copyright (C) 2007, 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_FUNC_REALLOC_GNU
   8 # -------------------
   9 # Test whether 'realloc (0, 0)' is handled like in GNU libc, and replace
  10 # realloc if it is not.
  11 AC_DEFUN([gl_FUNC_REALLOC_GNU],
  12 [
  13   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  14   dnl _AC_FUNC_REALLOC_IF is defined in Autoconf.
  15   _AC_FUNC_REALLOC_IF(
  16     [AC_DEFINE([HAVE_REALLOC_GNU], [1],
  17                [Define to 1 if your system has a GNU libc compatible 'realloc'
  18                 function, and to 0 otherwise.])],
  19     [AC_DEFINE([HAVE_REALLOC_GNU], [0])
  20      gl_REPLACE_REALLOC
  21     ])
  22 ])# gl_FUNC_REALLOC_GNU
  23
  24 # gl_FUNC_REALLOC_POSIX
  25 # ---------------------
  26 # Test whether 'realloc' is POSIX compliant (sets errno to ENOMEM when it
  27 # fails), and replace realloc if it is not.
  28 AC_DEFUN([gl_FUNC_REALLOC_POSIX],
  29 [
  30   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  31   AC_REQUIRE([gl_CHECK_MALLOC_POSIX])
  32   if test $gl_cv_func_malloc_posix = yes; then
  33     AC_DEFINE([HAVE_REALLOC_POSIX], [1],
  34       [Define if the 'realloc' function is POSIX compliant.])
  35   else
  36     gl_REPLACE_REALLOC
  37   fi
  38 ])
  39
  40 AC_DEFUN([gl_REPLACE_REALLOC],
  41 [
  42   AC_LIBOBJ([realloc])
  43   REPLACE_REALLOC=1
  44 ])