git.cworth.org Git - tar/blob - m4/utimes.m4

   1 # Detect some bugs in glibc's implementation of utimes.
   2 # serial 2
   3
   4 dnl Copyright (C) 2003-2005, 2009-2010 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # See if we need to work around bugs in glibc's implementation of
  10 # utimes from 2003-07-12 to 2003-09-17.
  11 # First, there was a bug that would make utimes set mtime
  12 # and atime to zero (1970-01-01) unconditionally.
  13 # Then, there was code to round rather than truncate.
  14 # Then, there was an implementation (sparc64, Linux-2.4.28, glibc-2.3.3)
  15 # that didn't honor the NULL-means-set-to-current-time semantics.
  16 # Finally, there was also a version of utimes that failed on read-only
  17 # files, while utime worked fine (linux-2.2.20, glibc-2.2.5).
  18 #
  19 # From Jim Meyering, with suggestions from Paul Eggert.
  20
  21 AC_DEFUN([gl_FUNC_UTIMES],
  22 [
  23   AC_CACHE_CHECK([whether the utimes function works],
  24                  [gl_cv_func_working_utimes],
  25   [
  26   AC_RUN_IFELSE([AC_LANG_SOURCE([[
  27 #include <sys/types.h>
  28 #include <sys/stat.h>
  29 #include <fcntl.h>
  30 #include <sys/time.h>
  31 #include <time.h>
  32 #include <unistd.h>
  33 #include <stdlib.h>
  34 #include <stdio.h>
  35 #include <utime.h>
  36
  37 int
  38 main ()
  39 {
  40   static struct timeval timeval[2] = {{9, 10}, {999999, 999999}};
  41   struct stat sbuf;
  42   char const *file = "conftest.utimes";
  43   FILE *f;
  44   time_t now;
  45   int fd;
  46
  47   int ok = ((f = fopen (file, "w"))
  48             && fclose (f) == 0
  49             && utimes (file, timeval) == 0
  50             && lstat (file, &sbuf) == 0
  51             && sbuf.st_atime == timeval[0].tv_sec
  52             && sbuf.st_mtime == timeval[1].tv_sec);
  53   unlink (file);
  54   if (!ok)
  55     exit (1);
  56
  57   ok =
  58     ((f = fopen (file, "w"))
  59      && fclose (f) == 0
  60      && time (&now) != (time_t)-1
  61      && utimes (file, NULL) == 0
  62      && lstat (file, &sbuf) == 0
  63      && now - sbuf.st_atime <= 2
  64      && now - sbuf.st_mtime <= 2);
  65   unlink (file);
  66   if (!ok)
  67     exit (1);
  68
  69   ok = (0 <= (fd = open (file, O_WRONLY|O_CREAT, 0444))
  70               && close (fd) == 0
  71               && utimes (file, NULL) == 0);
  72   unlink (file);
  73
  74   exit (!ok);
  75 }
  76   ]])],
  77        [gl_cv_func_working_utimes=yes],
  78        [gl_cv_func_working_utimes=no],
  79        [gl_cv_func_working_utimes=no])])
  80
  81   if test $gl_cv_func_working_utimes = yes; then
  82     AC_DEFINE([HAVE_WORKING_UTIMES], [1], [Define if utimes works properly. ])
  83   fi
  84 ])